flash中 ActionScript。解释下面这段的每一句什么意思。

发布网友发布时间：2023-01-03 18:59

共1个回答

热心网友时间：2023-10-12 05:03

package {
    //导入代码中所使用到的类包
    import flash.display.Sprite;
    import flash.events.Event;

    //声明名为 Circle 的类，该类继承自 Sprite 类
    public class Circle extends Sprite {
        //Ball类，从名字上看应该是一个小球元件
        private var ball:Ball;
        //角度
        private var angle:Number=0;
        //中心点坐标
        private var centerX:Number=200;
        private var centerY:Number=200;
        //半径
        private var radius:Number=50;
        //速度
        private var speed:Number=0.1;

        //Cricle的构造函数
        public function Circle() {
            //初始化
            init();
        }

        //初始化函数
        private function init():void {
            //声明一个Ball类的实例
            ball= new Ball();
            //添加到场景
            addChild(ball);
            //初始化坐标为0，0
            ball.x=0;
            ball.y=0;
            //监听EnterFrame事件
            addEventListener(Event.ENTER_FRAME,onEnterFrame);
        }

        //EnterFrame事件函数
        public function onEnterFrame(event:Event):void {
            //分别计算ball在圆圈路径上的x坐标和y坐标
            ball.x=centerX+Math.sin(angle)*radius;
            ball.y=centerY+Math.cos(angle)*radius;
            //角度递增
            angle+=speed;
        }
    }
}

这个Circle类的目的是让Ball的一个实例沿着以点(200,200)为圆心，50为半径的圆圈路径不停的移动。