易语言取进程用户名

发布网友 发布时间：2022-07-28 20:24

我来回答

共2个回答

热心网友 时间：2023-12-06 01:18

.版本 2
.子程序 取进程用户名, 文本型, 公开
.参数 进程ID, 整数型
.局部变量 hProcess, 整数型
.局部变量 hToken, 整数型
.局部变量 ptiUser, 字节集
.局部变量 pSid, 整数型
.局部变量 bSuccess, 逻辑型
.局部变量 cbBuf, 整数型
.局部变量 UserSize, 整数型
.局部变量 DomainSize, 整数型
.局部变量 User, 文本型
.局部变量 Domain, 文本型
hProcess ＝ OpenProcess (1024, 假, 进程ID)
.如果真 (hProcess ＝ 0)
返回 (字符 (0))
.如果真结束
.如果真 (OpenProcessToken (hProcess, 8, hToken) ＝ 假)
CloseHandle (hProcess)
返回 (字符 (0))
.如果真结束
CloseHandle (hProcess)
GetTokenInformation (hToken, 1, { }, 0, cbBuf)
ptiUser ＝ 取空白字节集 (cbBuf)
bSuccess ＝ GetTokenInformation (hToken, 1, ptiUser, cbBuf, 0)
pSid ＝ 取字节集数据 (ptiUser, #整数型, )
CloseHandle (hToken)
.如果真 (bSuccess ＝ 假)
返回 (字符 (0))
.如果真结束
LookupAccountSidA (字符 (0), pSid, 字符 (0), UserSize, 字符 (0), DomainSize, 0)
.如果真 (UserSize ＝ 0)
CloseHandle (hProcess)
返回 (字符 (0))
.如果真结束
User ＝ 取空白文本 (UserSize)
Domain ＝ 取空白文本 (DomainSize)
bSuccess ＝ LookupAccountSidA (字符 (0), pSid, User, UserSize, Domain, DomainSize, 0)
返回 (选择 (bSuccess, User, 字符 (0)))
.版本 2
.DLL命令 OpenProcess, 整数型, , "OpenProcess"
.参数 dwDesiredAccess, 整数型
.参数 bInheritHandle, 逻辑型
.参数 dwProcessId, 整数型
.DLL命令 CloseHandle, 逻辑型, , "CloseHandle"
.参数 hObject, 整数型
.DLL命令 OpenProcessToken, 逻辑型, "Advapi32.dll", "OpenProcessToken"
.参数 ProcessHandle, 整数型
.参数 DesiredAccess, 整数型
.参数 TokenHandle, 整数型, 传址
.DLL命令 GetTokenInformation, 逻辑型, "Advapi32.dll", "GetTokenInformation"
.参数 TokenHandle, 整数型
.参数 TokenInformationClass, 整数型
.参数 TokenInformation, 字节集, 传址
.参数 TokenInformationLength, 整数型
.参数 ReturnLength, 整数型, 传址
.DLL命令 LookupAccountSidA, 逻辑型, "Advapi32.dll"
.参数 lpSystemName, 文本型
.参数 lpSid, 整数型
.参数 lpName, 文本型
.参数 cchName, 整数型, 传址
.参数 lpReferencedDomainName, 文本型
.参数 cchReferencedDomainName, 整数型, 传址
.参数 peUse, 整数型, 传址
.DLL命令 GetCurrentProcessId, 整数型, "kernel32.dll", "GetCurrentProcessId"

.版本 2
.数据类型 TOKEN_USER
.成员 User, SID_AND_ATTRIBUTES
.数据类型 SID_AND_ATTRIBUTES
.成员 Sid, 整数型
.成员 Attributes, 字节集
.数据类型 SID
.成员 Revision, 字节型
.成员 SubAuthorityCount, 字节型
.成员 IdentifierAuthority, 字节型, , "6"
.成员 SubAuthority, 整数型, , "1"

热心网友 时间：2023-12-06 01:19

没分，汗