如何把VB.NET内部资源文件复制到磁盘上

发布网友发布时间：2022-11-02 09:39

共1个回答

热心网友时间：2023-10-23 06:09

可以查看附件，或则使用以下代码。应该注释的满全了。

随便建一个窗口工程，窗口代码帖入以下代码。

Imports System.IO
Imports System.Text
Imports System.Reflection

Public Class Form1
    Const ResName As String = "123.txt" ' 需要保存的资源名
    Const BufferSize As Integer = 4096  ' 复制时缓冲的大小

    Private Sub Demo()

        ' 变量声明
        Dim strDisplayText As StringBuilder ' 保存输出信息
        Dim strResName As String            ' 保存目标资源的名称

        ' 变量初始化
        strDisplayText = New StringBuilder()
        strResName = String.Empty

        ' 获取所有资源
        strDisplayText.AppendLine("文件中存在以下资源:")
        For Each strName As String In Assembly.GetExecutingAssembly.GetManifestResourceNames()
            strDisplayText.AppendLine("  " & strName)
            ' 获得目标资源的全名
            If strName.EndsWith("." & ResName) Then
                strResName = strName
            End If
        Next

        ' 目标资源不存在
        strDisplayText.AppendLine()
        If strResName = String.Empty Then
            strDisplayText.AppendLine("抱歉，没有找名为""" & ResName & """的资源")

        Else ' 复制资源的代码

            ' 打开资源文件，在End Using的时候自动关闭。
            Using ms As UnmanagedMemoryStream = Assembly.GetExecutingAssembly.GetManifestResourceStream(strResName)

                ' 打开磁盘文件，在End Using的时候自动关闭。
                Using fs As New FileStream("C:\" & ResName, FileMode.Create)

                    ' 变量声明
                    Dim Buffer(BufferSize - 1) As Byte  ' 复制文件时的缓冲数组
                    Dim ReadCount As Integer            ' 此次读取数据的数量

                    ' 还有数据可以读取的情况，一直循环
                    ReadCount = ms.Read(Buffer, 0, BufferSize)
                    While ReadCount > 0
                        fs.Write(Buffer, 0, ReadCount) ' 写入到磁盘文件
                        ReadCount = ms.Read(Buffer, 0, BufferSize)
                    End While

                End Using
            End Using
            strDisplayText.AppendLine("文件已经复制完毕。")
        End If

        ' 显示消息
        MessageBox.Show(strDisplayText.ToString())

    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Call Demo()
        End
    End Sub
End Class