能不能叫教我 如何通过MAC来批量修改IP、计算机名谢谢
发布网友
发布时间：2022-04-22 22:27
共1个回答
热心网友
时间：2023-09-06 04:09
1、新建一个文本，复制下面的代码。红字部分按自己的网络情况填写。保存为bat文件，比如：修改.bat
2、新建一个文本文件，保存为 MAC.ini。其中将要改的计算机信息放入。第一列为计算机名，第二列为ip地址，第三列为网关地址，第四列为mac地址,每台机子占一行。例如：
eeee 192.168.0.7 192.168.0.1 00-00-00-00-c0-0
edde 192.168.0.8 192.168.0.1 00-00-00-22-c0-0
ddde 192.168.1.9 192.168.1.1 00-02-00-00-c0-0
以下为批处理代码：
@echo off
color 0a
setlocal EnableDelayedExpansion
title 自动改IP、网关、计算机名
set mask=255.255.255.0
set DNS1=244.144.142.4
set DNS2=211.144.143.6
echo.
echo. 完成获取资料,请检查正确后按确认键开始执行修改任务
echo.
for /f "tokens=2 delims=:" %%M in ('ipconfig /all^|find /i "Physical Address"') do set Mac=%%M
echo. 本机 MAC地址: %Mac% (硬件获取)
set PCMAC=%MAC:~1%
echo.
for /f "tokens=1" %%a in ('type MAC.ini^|find /i "%PCMac%"') do (set pcname=%%a)
echo 本机计算机名: %pcname% (动态获取)
echo.
for /f "tokens=2" %%b in ('type MAC.ini^|find /i "%PCMac%"') do (set myip=%%b)
echo 本机 IP 地址: %myip% (动态获取)
echo.
for /f "tokens=3" %%c in ('type MAC.ini^|find /i "%PCMac%"') do (set mygw=%%c)
echo 本机网关地址: %mygw% (动态获取)
echo.
echo.*************************************************************************
echo 子网掩码: %mask% (静态获取)
echo. 本机DNS1: %DNS1% (静态获取)
echo. 本机DNS2: %DNS2% (静态获取)
echo.
echo 修改计算机器名ing...
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\ShellNoRoam" /v @ /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v "ComputerName" /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v "ComputerName" /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Services\Eventlog" /v "ComputerName" /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v "ComputerName" /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d "%pcname%" /f
reg add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" /v "Hostname" /t REG_SZ /d "%pcname%" /f
echo.
echo 开始设置网卡 IP 地址,掩码,网关,DNS
netsh interface ip set address name="本地连接" source=static addr=%myip% mask=%mask% gateway=%mygw% gwmetric=1
netsh interface ip set dns name="本地连接" source=static addr=%DNS1%
netsh interface ip add dns name="本地连接" addr=%DNS2% index=2
echo 设置网卡 IP 地址,掩码,网关,DNS完成
echo.
ipconfig/all
echo.
pause
