传奇脚本——行会收人
发布网友
发布时间：2022-04-29 18:10
共1个回答
热心网友
时间：2023-11-20 05:20
放出来只是供大家查考脚本勾架和多个方面结合运用的例子！
所以里面写脚本的时候难免有点不严谨（笑~）
大家可以仔细看下它的结构，举一反三弄出更多好玩的东西！
首先是NPC文件！
[@main]
#IF
checkcastlewar 0
#SAY
现在是攻沙时间，无法使用这个功能！\
#ACT
break
#IF
ISGUILDMASTER
CheckVar GLOBAL hangs1 = <$GUILDNAME>
#ACT
GOTO @行会收人管理
break
#IF
ISGUILDMASTER
CheckVar GLOBAL hangs1 =
#SAY
目前这个功能暂时无人使用！\
开通这个服务需要5元宝！\
<我有5元宝我要使用这个功能/@开通行会收人>\
#ACT
break
#IF
HAVEGUILD
#SAY
您已经加入一个行会，这里不是您来的地方了！\
#ACT
break
#IF
CheckVar GLOBAL hangs1 =
#SAY
暂时没有行会在这里发布收人广告！\
#elseact
MOV S2 <
INC S2 <$DATETIME>
INC S2 /AUTOCOLOR=224,251,252,253,254>
MOV P0 <$GLOBAL(hangd1)>
MOV P1 <$GLOBAL(hanggj1)>
MOV P2 <$GLOBAL(hangmf1)>
MOV P3 <$GLOBAL(hangds1)>
#elseSAY
<==============/SCOLOR=250><这里是寻仙传说的行会收人脚本/AUTOCOLOR=224,251,252,253,254><==============/SCOLOR=250>\
行会名称：<$GLOBAL(hangs1)>\
招收成员等级要求不低于：<$GLOBAL(hangd1)>\
招收成员最大攻击不低于：<$GLOBAL(hanggj1)>\
招收成员最大魔法不低于：<$GLOBAL(hangmf1)>\
招收成员最大道数不低于：<$GLOBAL(hangds1)>\
<(PS:战士申请时只会检测攻击！法师道士一样只检测本职业属性！)/AUTOCOLOR=224,251,252,253,254>\
<我达到要求了，我要申请加入此行会/@加入此行会>\
<============/SCOLOR=250><$STR(S2)><==============/SCOLOR=250>\
[@加入此行会]
#IF
CheckVar GLOBAL hangk1 =
CHECKLEVELEX > <$STR(P0)>
CheckJob Warrior
SMALL P1 <$MAXDC>
#ACT
CALCVAR GLOBAL hangk1 =1
CALCVAR GLOBAL hangm1 = <$USERNAME>
Gmexecute 开始提问 @申请加行会
DelayCall 7 @对方行会无人
messagebox 申请提交成功，请等待5秒后有结果！
break
#IF
CheckVar GLOBAL hangk1 =
CHECKLEVELEX > <$STR(P0)>
CheckJob Wizard
SMALL P2 <$MAXMC>
#ACT
CALCVAR GLOBAL hangk1 =1
CALCVAR GLOBAL hangm1 = <$USERNAME>
Gmexecute 开始提问 @申请加行会
DelayCall 7 @对方行会无人
messagebox 申请提交成功，请等待5秒后有结果！
break
#IF
CheckVar GLOBAL hangk1 =
CHECKLEVELEX > <$STR(P0)>
CheckJob Taoist
SMALL P3 <$MAXSC>
#ACT
CALCVAR GLOBAL hangk1 =1
CALCVAR GLOBAL hangm1 = <$USERNAME>
Gmexecute 开始提问 @申请加行会
DelayCall 7 @对方行会无人
messagebox 申请提交成功，请等待5秒后有结果！
#elseact
messagebox 对不起，您的人物属性达不到规定要求，或有人使用，请稍后再使用！
[@开通行会收人]
#IF
CHECKGAMEPOINT > 4
#ACT
GAMEGOLD - 5
CALCVAR GLOBAL hangs1 = <$GUILDNAME>
CALCVAR GLOBAL hangd1 = 1
CALCVAR GLOBAL hanggj1 = 1
CALCVAR GLOBAL hangmf1 = 1
CALCVAR GLOBAL hangds1 = 1
SAVEVAR GLOBAL hangd1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangd1.txt
SAVEVAR GLOBAL hanggj1 ..\QuestDiary\PAL变量\行会变量\收人相关\hanggj1.txt
SAVEVAR GLOBAL hangmf1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangmf1.txt
SAVEVAR GLOBAL hangds1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangds1.txt
SAVEVAR GLOBAL hangs1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangs1.txt
goto @行会收人管理
#elseact
messagebox 您身上的元宝不足！\这个服务，需要行会掌门花费5元宝！\
[@行会收人管理]
#SAY
<============/SCOLOR=250><这里是寻仙传说的行会收人脚本/AUTOCOLOR=224,251,252,253,254><==============/SCOLOR=250>\
行会名称：<$GLOBAL(hangs1)>\
<设置/@@InPutString163> 招收成员等级要求不低于：<$GLOBAL(hangd1)>\
<设置/@@InPutString164> 招收成员最大攻击不低于：<$GLOBAL(hanggj1)>\
<设置/@@InPutString165> 招收成员最大魔法不低于：<$GLOBAL(hangmf1)>\
<设置/@@InPutString166> 招收成员最大道数不低于：<$GLOBAL(hangds1)>\
<(PS:战士申请时只会检测攻击！法师道士一样只检测本职业属性！)/AUTOCOLOR=224,251,252,253,254>\
\
<========================================================/SCOLOR=250>\
[@对方行会无人]
#SAY
对方行会掌门及长老都不在线，申请失败！
[@@InPutString163]
#ACT
DELAYGOTO 1 ~InPutString163
[~InPutString163]
#ACT
CALCVAR GLOBAL hangd1 = <$STR(S0)>
SAVEVAR GLOBAL hangd1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangd1.txt
SENDMSG 5 招收成员最低等级要求设置成功！
goto @行会收人管理
break
[@@InPutString164]
#ACT
DELAYGOTO 1 ~InPutString164
[~InPutString164]
#ACT
CALCVAR GLOBAL hanggj1 = <$STR(S0)>
SAVEVAR GLOBAL hanggj1 ..\QuestDiary\PAL变量\行会变量\收人相关\hanggj1.txt
SENDMSG 5 招收成员最低攻击要求设置成功！
goto @行会收人管理
break
[@@InPutString165]
#ACT
DELAYGOTO 1 ~InPutString165
[~InPutString165]
#ACT
CALCVAR GLOBAL hangmf1 = <$STR(S0)>
SAVEVAR GLOBAL hangmf1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangmf1.txt
SENDMSG 5 招收成员最低魔法要求设置成功www.5uwl.net ！
goto @行会收人管理
break
[@@InPutString166]
#ACT
DELAYGOTO 1 ~InPutString166
[~InPutString166]
#ACT
CALCVAR GLOBAL hangds1 = <$STR(S0)>
SAVEVAR GLOBAL hangds1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangds1.txt
SENDMSG 5 招收成员最低道数要求设置成功！
goto @行会收人管理
break
放在 D:\mirserver\Mir200\Envir\MapQuest_def\QManage.txt 中的文件
[@申请加行会]
#ACT
MOV S0 <$RANKNAME>
GOTO @行会领导审核
[@行会领导审核]
#IF
CheckGuildMaster <$GLOBAL(hangs1)>
#SAY
玩家<$GLOBAL(hangm1)>请求加入您的行会！\
<同意/@同意> <不同意/@不同意>\
(PS：无选择5秒内自动拒绝！)\
#ACT
DelayCall 5 @自动拒绝加入
break
#IF
EQUAL S0 长老
CHECKOFGUILD <$GLOBAL(hangs1)>
#SAY
玩家<$GLOBAL(hangm1)>请求加入您的行会！\
<同意/@同意> <不同意/@不同意>
(PS：无选择5秒内自动拒绝！)
#ACT
DelayCall 5 @自动拒绝加入
[@同意]
#ACT
SendMsg 5 您同意了申请，恭喜[<$GLOBAL(hangm1)>]加入了您的行会！
HCall <$GLOBAL(hangm1)> @行会审核成功
CLEARDELAYGOTO
CLOSE
[@不同意]
#ACT
SendMsg 5 您拒绝了[<$GLOBAL(hangm1)>]的申请！
CALCVAR GLOBAL hangk1 =
HCall <$GLOBAL(hangm1)> @行会审核失败
CLEARDELAYGOTO
CLOSE
[@自动拒绝加入]
#SAY
由于5秒内无操作，所以自动帮你拒绝了申请！
#ACT
SendMsg 5 由于5秒内无操作，所以系统自动帮你拒绝了[<$GLOBAL(hangm1)>]的申请！
CALCVAR GLOBAL hangk1 =
HCall <$GLOBAL(hangm1)> @行会审核失败
CLOSE
[@行会审核成功]
#SAY
恭喜！您成功加入<$GLOBAL(hangs1)>行会！
#act
CLOSE
SendMsg 5 恭喜！您成功加入[<$GLOBAL(hangs1)>]行会！
CALCVAR GLOBAL hangk1 =
AddGuildMember <$GLOBAL(hangs1)>
CLEARDELAYGOTO
CLOSE
[@行会审核失败]
#SAY
对不起，您的加入行会申请被拒绝！
#act
SendMsg 5 对不起，您的申请被拒绝了！
CLEARDELAYGOTO
CLOSE 加载变量
;===============================================================================
;==========================测试行会收人脚本使用变量=============================
;===============================================================================
VAR String GLOBAL hangs1
VAR String GLOBAL hangm1
VAR Integer GLOBAL hangd1
VAR Integer GLOBAL hanggj1
VAR Integer GLOBAL hangmf1
VAR Integer GLOBAL hangds1
VAR Integer GLOBAL hangk1
LOADVAR GLOBAL hangs1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangs1.txt
LOADVAR GLOBAL hangm1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangm1.txt
LOADVAR GLOBAL hangd1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangd1.txt
LOADVAR GLOBAL hanggj1 ..\QuestDiary\PAL变量\行会变量\收人相关\hanggj1.txt
LOADVAR GLOBAL hangmf1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangmf1.txt
LOADVAR GLOBAL hangds1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangds1.txt
LOADVAR GLOBAL hangk1 ..\QuestDiary\PAL变量\行会变量\收人相关\hangk1.txt
如果再多用几个变量去* 再配合机器人对全局变量的控制可以让这个脚本形成按时间收费的功能！
有点能力的 可以为了防止长期有人点击申请来烦自己的话
能使用自定义命令 如：@暂时拒绝收人 这样命令结合脚本制作接收收人消息的开关！
